*  JieJie Microelectronics P-Spice Model Library
*  Filename:           JMSL1040AGDQ_P v.20230509.txt
*  Product Name:       JMSL1040AGDQ (PDFN5x6-8L-D)
*  Configuration:      Dual N+N channel Device
*  Data Sheet Rev.:    1.0
*  Release Date:       May 9, 2023
*  Junction Temp (Tj): -40C ~ 175C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, Jiangsu JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*

.subckt JMSL1040AGDQ D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.02
RS S 3 1E-006
RG G 17 2.62
CGS 3 G 3.6E-10
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00343*(TEMP-25))+((-2.00121E-6)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.3)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 2E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cbreak D 3 Cbreak 3.50702E-10
.MODEL Cbreak CAP (C = 1 VC1 = -0.01918 VC2 = 1.0713E-4)

.model NMOS NMOS
+LEVEL = 3                     
+VMAX = 1.0752E9               ETA = 1E-4                    
+VTO = 2.7                     TOX = 8E-10                   NSUB = 3.55E15                
+KP = 52                       U0 = 424                      KAPPA = 0.1                   
+GAMMA = 0.3                   PHI = 0.798625                THETA = 0.3                   
+DELTA = 30                    

.model DCGD D
+CJO = 8E-11                   VJ = 45                       M = 3.2                       

.model DSUB D
+IS = 1E-13                    N = 1.02                      RS = 0.01                     
+BV = 107                      xti = 0.2                     

.model DLIM D
+IS = 1E-4                     
.ends JMSL1040AGDQ


******************************************************************************************************
*  Copyright (C) 2023 JJM. All rights reserved.
******************************************************************************************************

